Qt Quick 3D (code name: demon render)

import QtQuick 2.12
import QtQuick.Window 2.12
import QtDemon 1.0

Window {
    id: window
    visible: true
    width: 1280
    height: 720

    // Viewport for 3D content
    DemonView3D {
        id: view
        anchors.fill: parent

        // Scene to view
        DemonNode {
            id: scene

            // To render anything to a 3D viewport, you need 3 things
            // Light, Camera, Model
            DemonLight {
                id: directionalLight
            }

            DemonCamera {
                id: camera
                // It's important that your camera is not inside your model
                // So move it back a big along the z axis
                // The Camera is implicitly facing up the z axis, so we should be looking towards
                // (0, 0, 0)
                z: -600
            }

            DemonModel {
                id: cubeModel
                // #Cube is one of the "built-in" primitive meshes
                // Other Options are #Cone, #Sphere, #Cylinder, #Rectangle
                source: "#Cube"

                // When using a Model, it is not enough to have a mesh source (ie "#Cube")
                // You also need to define what material to shade the mesh with. A Model can be
                // built up of multiple sub-meshes, so each mesh needs its own material
                // So materials are defined in an array, and order reflects which mesh to shade
                // All of the default primitive meshes contain one sub-mesh, so you only
                // need 1 material. 
                materials: [
                    DemonDefaultMaterial {
                        // We are using the DefaultMaterial which dynamically generates a shader
                        // based on what properties are set.  This means you don't need to write
                        // any shader code yourself.  In this case we just want the cube to have
                        // a red color.
                        id: cubeMaterial
                        diffuseColor: "red"
                    }
                ]
            }
        }
    }
}