qtcreatorplugin.pri 4.9 KB
Newer Older
1 2 3 4 5 6 7 8 9
depfile = $$replace(_PRO_FILE_PWD_, ([^/]+$), \\1/\\1_dependencies.pri)
exists($$depfile) {
    include($$depfile)
    isEmpty(QTC_PLUGIN_NAME): \
        error("$$basename(depfile) does not define QTC_PLUGIN_NAME.")
} else {
    isEmpty(QTC_PLUGIN_NAME): \
        error("QTC_PLUGIN_NAME is empty. Maybe you meant to create $$basename(depfile)?")
}
10
TARGET = $$QTC_PLUGIN_NAME
11

12 13 14 15 16
plugin_deps = $$QTC_PLUGIN_DEPENDS
plugin_recmds = $$QTC_PLUGIN_RECOMMENDS

include(../qtcreator.pri)

17 18
# for substitution in the .pluginspec
dependencyList = "<dependencyList>"
19
for(dep, plugin_deps) {
20 21 22
    include($$PWD/plugins/$$dep/$${dep}_dependencies.pri)
    dependencyList += "        <dependency name=\"$$QTC_PLUGIN_NAME\" version=\"$$QTCREATOR_VERSION\"/>"
}
23
for(dep, plugin_recmds) {
24 25 26 27 28 29
    include($$PWD/plugins/$$dep/$${dep}_dependencies.pri)
    dependencyList += "        <dependency name=\"$$QTC_PLUGIN_NAME\" version=\"$$QTCREATOR_VERSION\" type=\"optional\"/>"
}
dependencyList += "    </dependencyList>"
dependencyList = $$join(dependencyList, $$escape_expand(\\n))

30 31 32
# use gui precompiled header for plugins by default
isEmpty(PRECOMPILED_HEADER):PRECOMPILED_HEADER = $$PWD/shared/qtcreator_gui_pch.h

con's avatar
con committed
33
isEmpty(PROVIDER) {
34
    PROVIDER = QtProject
35
} else {
36
    LIBS += -L$$IDE_PLUGIN_PATH/QtProject
con's avatar
con committed
37 38
}

39 40 41
isEmpty(USE_USER_DESTDIR) {
    DESTDIR = $$IDE_PLUGIN_PATH/$$PROVIDER
} else {
42 43 44 45 46 47 48 49 50
    win32 {
        DESTDIRAPPNAME = "qtcreator"
        DESTDIRBASE = "$$(LOCALAPPDATA)"
        isEmpty(DESTDIRBASE):DESTDIRBASE="$$(USERPROFILE)\Local Settings\Application Data"
    } else:macx {
        DESTDIRAPPNAME = "Qt Creator"
        DESTDIRBASE = "$$(HOME)/Library/Application Support"
    } else:unix {
        DESTDIRAPPNAME = "qtcreator"
51
        DESTDIRBASE = "$$(XDG_DATA_HOME)"
52
        isEmpty(DESTDIRBASE):DESTDIRBASE = "$$(HOME)/.local/share/data"
53
        else:DESTDIRBASE = "$$DESTDIRBASE/data"
54
    }
55
    DESTDIR = "$$DESTDIRBASE/QtProject/$$DESTDIRAPPNAME/plugins/$$QTCREATOR_VERSION/$$PROVIDER"
56
}
con's avatar
con committed
57 58 59 60
LIBS += -L$$DESTDIR

# copy the plugin spec
isEmpty(TARGET) {
61
    error("qtcreatorplugin.pri: You must provide a TARGET")
con's avatar
con committed
62 63
}

64 65 66 67 68 69 70 71
isEqual(QT_MAJOR_VERSION, 5) {

defineReplace(stripOutDir) {
    return($$relative_path($$1, $$OUT_PWD))
}

} else { # qt5

72 73 74 75 76
defineReplace(stripOutDir) {
    1 ~= s|^$$re_escape($$OUT_PWD/)||$$i_flag
    return($$1)
}

77 78
} # qt5

79 80 81 82
PLUGINSPEC = $$_PRO_FILE_PWD_/$${TARGET}.pluginspec
PLUGINSPEC_IN = $${PLUGINSPEC}.in
exists($$PLUGINSPEC_IN) {
    OTHER_FILES += $$PLUGINSPEC_IN
83
    QMAKE_SUBSTITUTES += $$PLUGINSPEC_IN
84 85 86 87 88 89 90 91
    PLUGINSPEC = $$OUT_PWD/$${TARGET}.pluginspec
    copy2build.output = $$DESTDIR/${QMAKE_FUNC_FILE_IN_stripOutDir}
} else {
    # need to support that for external plugins
    OTHER_FILES += $$PLUGINSPEC
    copy2build.output = $$DESTDIR/${QMAKE_FUNC_FILE_IN_stripSrcDir}
}
copy2build.input = PLUGINSPEC
92
isEmpty(vcproj):copy2build.variable_out = PRE_TARGETDEPS
93
copy2build.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
94
copy2build.name = COPY ${QMAKE_FILE_IN}
95
copy2build.CONFIG += no_link no_clean
96
QMAKE_EXTRA_COMPILERS += copy2build
con's avatar
con committed
97

98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113
greaterThan(QT_MAJOR_VERSION, 4) {
#   Create a Json file containing the plugin information required by
#   Qt 5's plugin system by running a XSLT sheet on the
#   pluginspec file before moc runs.
    XMLPATTERNS = $$targetPath($$[QT_INSTALL_BINS]/xmlpatterns)

    pluginspec2json.name = Create Qt 5 plugin json file
    pluginspec2json.input = PLUGINSPEC
    pluginspec2json.variable_out = GENERATED_FILES
    pluginspec2json.output = $${TARGET}.json
    pluginspec2json.commands = $$XMLPATTERNS -no-format -output $$pluginspec2json.output $$PWD/pluginjsonmetadata.xsl $$PLUGINSPEC
    pluginspec2json.CONFIG += no_link
    moc_header.depends += $$pluginspec2json.output
    QMAKE_EXTRA_COMPILERS += pluginspec2json
}

con's avatar
con committed
114
macx {
115
    !isEmpty(TIGER_COMPAT_MODE) {
con's avatar
con committed
116
        QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../PlugIns/$${PROVIDER}/
117 118
    } else {
        QMAKE_LFLAGS_SONAME = -Wl,-install_name,@rpath/PlugIns/$${PROVIDER}/
119
        QMAKE_LFLAGS += -Wl,-rpath,@loader_path/../../,-rpath,@executable_path/../
120
    }
con's avatar
con committed
121 122
} else:linux-* {
    #do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
Daniel Molkentin's avatar
Daniel Molkentin committed
123
    QMAKE_RPATHDIR += \$\$ORIGIN
con's avatar
con committed
124
    QMAKE_RPATHDIR += \$\$ORIGIN/..
Daniel Molkentin's avatar
Daniel Molkentin committed
125
    QMAKE_RPATHDIR += \$\$ORIGIN/../..
con's avatar
con committed
126 127 128 129 130 131
    IDE_PLUGIN_RPATH = $$join(QMAKE_RPATHDIR, ":")
    QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${IDE_PLUGIN_RPATH}\'
    QMAKE_RPATHDIR =
}

contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
132

133
TEMPLATE = lib
con's avatar
con committed
134
CONFIG += plugin plugin_with_soname
135
linux*:QMAKE_LFLAGS += $$QMAKE_LFLAGS_NOUNDEF
136

137
!macx {
Daniel Molkentin's avatar
Daniel Molkentin committed
138
    target.path = $$QTC_PREFIX/$$IDE_LIBRARY_BASENAME/qtcreator/plugins/$$PROVIDER
Daniel Molkentin's avatar
Daniel Molkentin committed
139
    pluginspec.files += $${TARGET}.pluginspec
Daniel Molkentin's avatar
Daniel Molkentin committed
140
    pluginspec.path = $$QTC_PREFIX/$$IDE_LIBRARY_BASENAME/qtcreator/plugins/$$PROVIDER
Daniel Molkentin's avatar
Daniel Molkentin committed
141
    INSTALLS += target pluginspec
142
}
dt's avatar
dt committed
143

Orgad Shaneh's avatar
Orgad Shaneh committed
144 145 146
MIMETYPES = $$_PRO_FILE_PWD_/$${TARGET}.mimetypes.xml
exists($$MIMETYPES):OTHER_FILES += $$MIMETYPES

147
TARGET = $$qtLibraryName($$TARGET)
dt's avatar
dt committed
148