diff --git a/qtcreator.pro b/qtcreator.pro
index 7b63cbb82bdfecc771e8e3bafe1301b260222f5f..09b416cb5737eb4acda24318781c3057d4dab79d 100644
--- a/qtcreator.pro
+++ b/qtcreator.pro
@@ -16,3 +16,21 @@ unix:!macx:!isEmpty(copydata):SUBDIRS += bin
 
 OTHER_FILES += dist/copyright_template.txt \
     $$files(dist/changes-*)
+
+macx {
+    APPBUNDLE = "$$OUT_PWD/bin/Qt Creator.app"
+    deployqt.commands = macdeployqt "$${APPBUNDLE}" \
+        -executable="$${APPBUNDLE}/Contents/MacOS/qmlpuppet.app/Contents/MacOS/qmlpuppet" \
+        -executable="$${APPBUNDLE}/Contents/Resources/qtpromaker" \
+        -executable="$${APPBUNDLE}/Contents/MacOS/qmlprofiler"
+    deployqt.depends = default
+    bindist.commands = 7z a -mx9 $$OUT_PWD/qtcreator$(INSTALL_POSTFIX).7z "$$OUT_PWD/bin/Qt Creator.app/"
+} else {
+    deployqt.commands = $$PWD/scripts/deployqt.py -i $(INSTALL_ROOT)
+    win32:deployqt.commands ~= s,/,\\\\,g
+    deployqt.depends = install
+    bindist.commands = 7z a -mx9 $$OUT_PWD/qtcreator$(INSTALL_POSTFIX).7z $(INSTALL_ROOT)
+    win32:bindist.commands ~= s,/,\\\\,g
+}
+bindist.depends = deployqt
+QMAKE_EXTRA_TARGETS += deployqt bindist